複素数と有理数
Juliaには定義済みの型として複素数型と有理数型を備えており、すべての標準的な算術演算子と初等関数に対応しています。 変換と昇格が定義されているために、定義済みの型の組み合わせに対しては、プリミティブ型も複合型も、期待通りに動きます。
複素数
グローバル定数の imには複素数の i が束縛されており、-1の平方根を表しています。 インデックスによく使われる変数iは、グローバル変数にすると害があるでしょう。 Juliaでは、数値リテラルを識別子の前に置くと係数になるので、 複素数の構文を、この定数を使って、便利に、従来の数学表記に似せることができます。
julia> 1 + 2im
1 + 2im複素数の標準的な算術演算はすべて実行可能です。
julia> (1 + 2im)*(2 - 3im)
8 + 1im
julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im
julia> (1 + 2im) + (1 - 2im)
2 + 0im
julia> (-3 + 2im) - (5 - 1im)
-8 + 3im
julia> (-1 + 2im)^2
-3 - 4im
julia> (-1 + 2im)^2.5
2.729624464784009 - 6.9606644595719im
julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im
julia> 3(2 - 5im)
6 - 15im
julia> 3(2 - 5im)^2
-63 - 60im
julia> 3(2 - 5im)^-1.0
0.20689655172413796 + 0.5172413793103449im昇格のしくみによって、異なる型の組み合わせでもちゃんと動くことが保証されています。
julia> 2(1 - 1im)
2 - 2im
julia> (2 + 3im) - 1
1 + 3im
julia> (1 + 2im) + 0.5
1.5 + 2.0im
julia> (2 + 3im) - 0.5im
2.0 + 2.5im
julia> 0.75(1 + 2im)
0.75 + 1.5im
julia> (2 + 3im) / 2
1.0 + 1.5im
julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im
julia> 2im^2
-2 + 0im
julia> 1 + 3/4im
1.0 - 0.75im3/4im == 3/(4*im) == -(3/4*im)となることに注意してください。リテラル係数の方が除算より結合がつよいのです。
julia> z = 1 + 2im
1 + 2im
julia> real(1 + 2im) # real part of z
1
julia> imag(1 + 2im) # imaginary part of z
2
julia> conj(1 + 2im) # complex conjugate of z
1 - 2im
julia> abs(1 + 2im) # absolute value of z
2.23606797749979
julia> abs2(1 + 2im) # squared absolute value
5
julia> angle(1 + 2im) # phase angle in radians
1.1071487177940904通常通り、複素数の絶対値 (abs)は０からの距離です。 abs2は、複素数の絶対値の二乗で、特に複素数の場合に、平方根の計算をさけるために使われます。 angleはラジアンによる位相角（偏角としても知られています）を返します。 その他すべての初等関数も複素数に対して定義されています。
julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im
julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im
julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991518im
julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im
julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im通常、数学的な関数は、実数に対しては実数を、複素数に対しては複素数を返す点に注意してください。 例えば、 -1 == -1 + 0imが成り立ちますが、sqrtは-1と-1 + 0imで挙動が違います。
julia> sqrt(-1)
ERROR: DomainError with -1.0:
sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
Stacktrace:
[...]
julia> sqrt(-1 + 0im)
0.0 + 1.0im数値リテラル係数表記は変数から複素数をつくる際には機能しません。 かわりに、掛け算を明示的に書く必要があります。
julia> a = 1; b = 2; a + b*im
1 + 2imしかし、これは推奨されません。 実部と虚部から直接、複素数をつくるには、関数complexを使ってください。
julia> a = 1; b = 2; complex(a, b)
1 + 2imこの作り方によって、乗算・加算を除くことができます。 特殊な浮動小数点数の値のセクションで述べた、InfやNaNは、複素数の実部や虚部に 使うことができます。
julia> 1 + Inf*im
1.0 + Inf*im
julia> 1 + NaN*im
1.0 + NaN*im有理数
Juliaには、整数の比を正確に表現するために、有理数型があります。 有理数は、//を使って、構成します。
julia> 2//3
2//3有理数の分子と分母に公約数がある場合、分母が非負である最小の数に約分されます。
julia> 6//9
2//3
julia> -4//8
-1//2
julia> 5//-15
-1//3
julia> -4//-12
1//3この正規化された形式は、整数の比に対して一意的なので、有理数の等価性は分子と分母の等価性を検査すればわかります。 有理数の標準化された分子と分母は、関数のnumerator と denominatorを使って得ることができます。
julia> numerator(2//3)
2
julia> denominator(2//3)
3直接、分子と分母を比較する必要は通常ありません。 標準的な算術・比較演算子有理数値に対して定義されているからです。
julia> 2//3 == 6//9
true
julia> 2//3 == 9//27
false
julia> 3//7 < 1//2
true
julia> 3//4 > 2//3
true
julia> 2//4 + 1//6
2//3
julia> 5//12 - 1//4
1//6
julia> 5//8 * 3//12
5//32
julia> 6//5 / 10//7
21//25有理数は簡単に浮動小数点数に変換することができます。
julia> float(3//4)
0.75有理数から浮動小数点数への変換は、a == 0かつb == 0の場合を除く任意の整数値aとbに対して、 下記の式に記した等価性が成り立つことを尊重しています。
julia> a = 1; b = 2;
julia> isequal(float(a//b), a/b)
true無限の有理数も構成可能です。
julia> 5//0
1//0
julia> -3//0
-1//0
julia> typeof(ans)
Rational{Int64}しかし、NaNの有理数値は構成できません。
julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
Stacktrace:
[...]たいていの場合、昇格のしくみのおかげで、苦労することなく他の数値型といっしょに使うことができます。
julia> 3//5 + 1
8//5
julia> 3//5 - 0.5
0.09999999999999998
julia> 2//7 * (1 + 2im)
2//7 + 4//7*im
julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im
julia> 3//2 / (1 + 2im)
3//10 - 3//5*im
julia> 1//2 + 2im
1//2 + 2//1*im
julia> 1 + 2//3im
1//1 - 2//3*im
julia> 0.5 == 1//2
true
julia> 0.33 == 1//3
false
julia> 0.33 < 1//3
true
julia> 1//3 - 0.33
0.0033333333333332993